Reaktor87 (Sinclair ZX Spectrum) by lupoman

[REAKTOR87] -------------------------------------------------------------------

BY LUIS PIERI

[COMPO] -----------------------------------------------------------------------

CATEGORY  : PUR-120

LINK      : https://lupoman.itch.io/Reaktor87

         

DATE      : 25-MAR-2025 TO 31-MAR-2025

COMPO     : BASIC 10 LINER CONTEST

            https://gkanold.wixsite.com/homeputerium/rules2025

CATEGORY  : PUR-120            

DEADLINE  : April 5th, 2025

[IDEA] ------------------------------------------------------------------------

Defend the core of the Reaktor 87 (Rel87 model) from contaminated particles.

Control your Proton beam with the "E" key to move up, "D" key to move down.

Shoot a beam to the left with the "O" key and to the right with the "P" key.

Destroy all incoming particles before its too late!

Watch out! some particles can avoid your beam and you need to shoot it again

(Totally not a bug... just a feature)

The left and right scroll effect is created changing only the attributes with LPRINT Hack! (redirecting LPRINT TO attrib RAM from https://blog.jafma.net/2020/08/29/efficient-basic-coding-for-the-zx-spectrum-v/#en_5)

We create UDG as columns of 8 attrib rows to be lprinted

The level is a string with all the udg (to be used as attrib data) to be LPrinted.

[FILES] -----------------------------------------------------------------------

In the ZIP file you will find:

- Reaktor87.tap    : the basic program to be loaded in the ZX Spectrum or in an

                     emulator (see help section)

- Reaktor87.jpg    : Screenshot of the game

- Reaktor87.gif    : An animated gif to show the gameplay

- Reaktor87.bas    : The version to be converted into .TAP developed in a modern 

                     computer, much easier to work with and the converted with

                     ZMakeBas (https://github.com/utz82/zmakebas)

- proof-pur120.jpg : Capture of the output of the ZX Basic Utility:

                     "Ten Liner Counter" from Matthew Begg

- Reaktor87.txt    : This file.     

               

[TIPS] ------------------------------------------------------------------------

  - Its better to tap the keys than to left it pressed.

  - Some particles would need more than one shot.

  - Try to destroy the closest first.

  - If there're more particles left in the rows leverage that and destroy all

  - When you need to move severals rows, shot a beam to take advantage of the time spent moving.

  - Strategy is more important than reflexes.

[CODE EXPLANATION] ------------------------------------------------------------

  - The code below is formated to be converted with the utility ZMakeBas.

  - Once converted the lines are much shorter in the ZX Basic.

  - You can see the final listing opening the .TAP file on the emulator.

  - Use Boolean expressions directly to the vars in order to save Ifs

  - Use calculated ATTRIB RAM positions to save calculation time

  - The speed is achived avoiding printing graphics, in the main loop we only update the attributes (ink and paper), the UDG are printed at the start only.

    To erase a invader we only need to put attrib to 0 (black ink with black paper).

  - ZX Spectrum attrib memory starts at 22528 to 22528+768  (23296)

  - The first UDG char is 144 = UDG "A"

  - The particles have 1 UDG for each Y position and different colors, all bright on, paper black.

  - So in total we need 11 UDGS (1 ship, 1 shot, 8 particles and 1 for the core)

    Level design (32 cols x 8 rows)

    00000000001111111111222222222233
    01234567890123456789012345678901
   1...C...........K................  CHR 146
   2.....D.........K................  CHR 147
   3.......E.......K................  CHR 148
   4.....F.........K................  CHR 149
   5........G......K................  CHR 150
   6......H........K................  CHR 151
   7.......I.......K................  CHR 152
   8.........J.....K................  CHR 153

  - When the player shot collides with particle, the pos in the string is replaced with an space char # in the pos in S$

  - Also the attrib pos of the shot is poked with red paper and ink, and shot is reset

# LINE 1 ----------------------------------------------------------------------========================================

# Load the UDG data, set the colors and border, print the name of the game

#

1 RANDOMIZE:                                              # Seed the random generator

  RESTORE 9:                                              # Start to read data from line 9

  FOR F=0TO87:READ A:POKE USR"a"+F,A+(F>15)*64:NEXT F:    # Poke all the 11 UDG needed

  BRIGHT 1:PAPER 0:INK 1:BORDER 0:CLS:                    # Set the colors of the game

  PRINT"REAKTOR-87":                                      # Print Title

  LET H=0:LET J=1                                         # Init hiscore and flag for spacing particles

# LINE 2 ----------------------------------------------------------------------========================================

# Init vars

# Var Y: Ship attrib location in RAM

# Var M: Shot attrib location in RAM

# Var N: Shot pos in the string of the level

# Var S: Score

# Var H: Hiscore

# Var C: for animation

# Var I: Holds VelX (-1 or 1) of the beam shot

# Var J: Flag for spacing blocks

# Var S$: The level, it should be always of len 32, the col 16 its always udg K "the core"

#

2 PRINT AT 4,0;"HI:";H:                                  # Print new hiscore

  LET Y=22895:LET I=0:LET M=Y:LET N=0:LET S=0:LET C=1:   # Init all the vars

  LET S$="        ":LET S$=S$+S$+S$+S$                   # Creates new empty level

# LINE 3 ----------------------------------------------------------------------========================================

# PRINT BACKGROUND

# 1 column of ship x 8 rows

# 31 columns of cannons x 8 rows

                                        

3 PRINT "1P:0  ":                                                           # Print new score

  FOR G=8 TO 15:                                                            # Loop the rows/cols

   FOR F=0 TO 15:                                                           # of the middle of screen

    PRINT AT G,15;"\a";AT G,F*2;"\b\b";AT7,F*2;"\''\''";AT16,F*2;"\..\..":  # Print the UDG to be shown

   NEXT F:                                                                  # Also the barriers of the

  NEXT G                                                                    # playfield

# LINE 4 OK ----------------------------------------------------------------------========================================

# Pointer the LPRINT to the Attrib RAM (LPrint Hack)

# Scroll half the level left to the center and the other half to the right

# 

4 POKE 23680,0:POKE 23681,89:                       # Point LPRINT to Attrib RAM (89*256 + 0)

  IF C=1 THEN                                       # If its time to scroll

   LET S$= CHR$(32+(114+INT(RND*8))*(J=1)) +        # Feed the leftmost with a new random particle

           S$(TO14)+                                # scroll the left part right to the center

           "\k"+                                    # make sure the center is the core

           S$(18TO32)+                              # scroll the right part left to the center

           CHR$(32+(114+INT(RND*8))*(J=1)):         # Feed the rightmost with a new random particle

   LET J=NOT J                                      # Reset flag to keep an column space between particles

# LINE 5 ----------------------------------------------------------------------========================================

# Read last key pressed, reset lastkey, calculate new ship position and check for fire beam shots left/right

#

5 LET O=PEEK 23560:POKE 23560,0:                          # Check for the lastkey pressed and reset it.

  LET Y=Y-(O=101 AND Y>22799)*32+(O=100 AND Y<23023)*32:  # Calculate new attrib coord of the ship (check for "E" and "D")

  IF I=0 THEN IF O=112 OR O=111 THEN                      # If there's no shot fired and O or P were pressed

   LET I=(O=112)-(O=111):LET M=Y:LET N=15:BEEP .01,1      # if its true init beam shot

# LINE 6 ----------------------------------------------------------------------========================================

# Update the level, after the scroll 

# We don't really print anything, just change attributes using the LPRINT attr hack (89*256 = 22784),

# to print a string to ATTR RAM in the ZX Spectrum)

# Poke the attrib of the ship (Beam Gun) to update position

# Check if an particle/block is about to reach the core if so its game over

6 LPRINT S$:                                       # Print the (atrib) level

  POKE Y,87:                                       # Show ship (beam gun)

  LET C=(C+0.125)*(C<1):                           # Update counter for level scroll

  IF CODE S$(15)>32 OR CODE S$(17)>32 THEN         # Check if there is a particle near the core

   BORDER 2:PRINT AT 7,11;"\{16}\{06}GAME OVER":   # if so is Game Over

   BEEP 1.5,-50:BORDER 0:                          # Doom sound

   LET H=H+(S-H)*(S>H):                            # Check if score is greater than highscore

   GO TO 2                                         # Restart the game

# LINE 7 ----------------------------------------------------------------------========================================

# Update beam shot position, and "print" it(we dont really print anything, just change attrib col to show the UDG beneath)

# also check if shot is going off screen

#          

7 LET M=M+I:LET N=N+I:                 # Update shot position (in attr ram and in the string coords)

  POKE M,120*(M<23165):                # Change attrib color depending if shot is in the level

  IF N>26 OR N<5 THEN                  # Check if the shot goes beyond left and right limits

   LET I=0:LET M=23168:LET N=0         # if so reset beam shot

# LINE 8 ----------------------------------------------------------------------========================================

# Check if a beam shot hit a particle, we check for map udg codes to pos in screen

# and then calculate the udg pos of the shot

# if it coincides update score, make sound, clear particle, reset shot

#

8 IF I<>0 AND CODE S$(N+1+I)=146+INT((M-22784)/32) THEN   # Check if shot fired and the char Y is the the same and shot Y

   POKE M,0: POKE M+I,82:                                 # Delete the shot, put an "explosion" 

   LET S$(N+1+I)=" ":                                     # Delete the particle in the level string

   LET S=S+1:                                             # Update score

   PRINT AT 5,0;"1P:";S:                                  # Print new score

   BEEP .05,-50:                                          # Explosion sound

   LET I=0:LET M=23168:LET N=0                            # Reset beam shot

# LINE 9 ----------------------------------------------------------------------========================================

# End of loop

# UDG DATA USR "A" Ship, "B" Block/Missile, and 3 "C", "D", E" particles attrib positions

# for saving chars, make all data from UDG "c" = data-64 and in the poke add 64

#

9 GO TO 4:    # Back to the start of the main loop

  DATA 60,126,255,36,36,255,126,60,  255,255,255,231,231,255,255,255, 1,0,0,0,0,0,0,0, 0,2,0,0,0,0,0,0, 0,0,3,0,0,0,0,0

# LINE 10 ---------------------------------------------------------------------========================================

# UDG DATA USR "F", "G", "H", "I", "J" for 8 lines of blocks

#

# So in total we need 10 UDGS (1 ship, 1 cannon, 8 x dreadnought)

# Level design (32 cols x 8 rows):

#  00000000001111111111222222222233

#  01234567890123456789012345678901

# 1...C...........K................  CHR 146

# 2.....D.........K................  CHR 147

# 3.......E.......K................  CHR 148

# 4.....F.........K................  CHR 149

# 5........G......K................  CHR 150

# 6......H........K................  CHR 151

# 7.......I.......K................  CHR 152

# 8.........J.....K................  CHR 153

#

10 DATA  0,0,0,4,0,0,0,0, 0,0,0,0,5,0,0,0, 0,0,0,0,0,6,0,0, 0,0,0,0,0,0,2,0, 0,0,0,0,0,0,0,3, 18,18,18,18,18,18,18,18

[END] -------------------------------------------------------------------------