A downloadable game

Minefield von Rainer Kappler (Masterware Entertainment)

fuer Commodore VC-20 Grundversion

https://www.facebook.com/rainer.kappler.5

Februar 2022

---

Spielbeschreibung:

Du stehst mit deinem Panzer vor einem Minenfeld und musst die Strasse auf der anderen Seite erreichen.

Mit der Taste A steuerst du den Panzer nach links und der Taste D nach rechts.

Wenn du auf eine Mine faehrst, ist das Spiel zu Ende. Mit jedem Level wird das Spiel schneller.


Listing:

1 print"{clear}{home}{white}{reverse on}{cm b}{reverse off}@{reverse on}{cm b}y{reverse on}{cm b}{reverse off}@{reverse on}{cm b}{reverse off}@xx{reverse on}{sh +}{cm b*4}C{reverse off}@@x<<x@@":
fori=0to23:poke7168+i,peek(7680+i):next:sp=500:le=1:sc=0
2 print"{clear}":fori=0to7:poke7424+i,0:next:poke36869,255:poke657,128:poke36879,221:f=30720:ifsp<=0thensp=0
3 fori=0to21:poke7702+f+i,0:poke7702+i,0:next:t=8175:poket+f,6:poket,1:poke8185,2:poke8185+f,0
4 fori=0to79:a=int(rnd(1)*396):poke7724+a+f,0:poke7724+a,2:next
5 a(0)=17:r(0)=-1:a(1)=18:r(1)=1:print"{home}{reverse on}{black}l"le;"{blue}sc"sc
6 d=-22:fori=0to1:ifpeek(197)=a(i)thend=r(i)
7 next:lc=peek(t+d):poket,32:t=t+d:poket+f,6:poket,1:sc=sc+1:fori=0tosp:next
8 iflc=2thenprint"{home}{reverse on}{red}"tab(13)"game over":poket+f,2:poke198,0:wait198,1:print"{clear}":sc=0:le=1:sp=500:goto2
9 iflc=0thenprint"{home}{reverse on}{blue}"tab(13)"well done":le=le+1:fori=0to2000:next:sp=sp-50:goto2
10 goto5:rem minefield (c) 2022 by rainer kappler


Programmbeschreibung:

1. Bildschirm loeschen, Grafikdaten laden, Startgeschwindigkeit setzen und Level auf eins. Score auf null.

2. Bildschirm loeschen, Grafikmodus einschalten und Bildschirmfarbe festlegen, Farbvariable, testen ob Hoechstgeschwindigkeit erreicht.

3. Strasse zeichnen und die Startposition des blauen Panzers setzen und zeichnen.

4. Minen auf zufaelligen Positionen setzen und zeichnen.

5. Tastaturbelegung und Richtung in Variablen festlegen, Level und Score in der ersten Bildschirmzeile anzeigen.

6. Variable für automatische Bewegung des Panzers nach oben festlegen. Schleife zur Tastaturabfrage.

7. Letztes Hintergrundzeichen speichern. Panzer loeschen und auf neuer Position zeichnen. Score um eins erhoehen und Warteschleife.

8. Ist der Panzer auf eine Mine gefahren? Dann Spielende. Panzer rot faerben. Warten auf Tastendruck, Bildschirm loeschen, Variablen zuruecksetzen und zurueck zu Zeile 2 springen.

9. Hat der Panzer die Strasse erreicht? Dann Level geschafft. Level erhoehen. Zwei Sekunden warten. Geschwindigkeit erhoehen und zu Zeile 2 springen.

10. Zurueck zu Zeile 5. Credits.


Download

Download
minefield.d64 170 kB
Download
Minefield.txt 3 kB

Install instructions

Programm laden mit WinVice (VC-20 Emulator xvic):

Einstellungen -> VIC20-Einstellungen -> Keine Speichererweiterung

Datei -> Disk Image einlegen -> Drive 8 -> remember 20.d64

Tippe “LOAD “MINEFIELD”,8 ein und Return druecken.

Wenn das Programm geladen wurde, "RUN" eintippen und Return druecken.

Leave a comment

Log in with itch.io to leave a comment.