C1P-Bomber by Hamilton Davies

1 S=54106:T=S+1:U=T+1:P=53635:E=P+1:FOR I=1 TO 23:?:NEXT I
2 U=T:T=S:S=S-1:IF S=54083 THEN S=54106
3 E=P:P=P+1:IF P=53658 THEN P=53635
4 POKE E,32:POKE P,237:POKE S,181:POKE T,182:POKE U,32
5 POKE 530,1:POKE 57088,253:IF PEEK(57088)=239 THEN B=P
6 IF B>0 THEN POKE B,32:B=B+32:POKE B,92:IF B=S GOTO 9
7 IF B>54139 THEN POKE B,32:B=0
8 FOR I=1 TO 10:NEXT I:GOTO 2
9 FOR I=0 TO 9:POKE S-I*33,174-I:POKE T-I*31,165+I:NEXT I
10 FOR I=1 TO 1000:NEXT I:?:W=W+1:? "SCORE: ";W:GOTO 1
98 REM
99 REM ****************** INSTRUCTIONS **********************
100 REM C1P BOMBER BY Hamilton Davies (HamiMiami@hotmail.com)
101 REM Eumlator: https://www.pcjs.org/machines/osi/c1p/
102 REM Click RESET
103 REM Click RUN
104 REM Type C then press ENTER twice for OK prompt
105 REM Click CHOOSE FILE button
106 REM Select this file from the where it was saved on disk
107 REM Click MOUNT (this will LOAD and RUN the program)
108 REM Press the SPACEBAR to bomb the ship
109 REM
1000 REM ***************** COMMENTS ************************
1001 REM Initialize the ship and plane and clear screen
1002 REM Move ship, check for offscreen and reset
1003 REM Move plane, check for offscreen and reset
1004 REM Draw the ship and plane onscreen
1005 REM Stop keyboard scan:check for spacebar press:drop bomb
1006 REM If bomb dropped move it and check for hit
1007 REM If bomb misses reset it
1008 REM Delay loop: next time slice
1009 REM Explosion
1010 REM Delay loop: increment score: next time slice
2000 REM 
2001 REM This was a challenging but fun exercise.
2002 REM The OSI C1P was my first computer back in 1979.
2003 REM I had not written an OSI C1P program in nearly 40 years.
2004 REM The real challenge was the C1P line length limit.