Zezito Back to Basics (C64) by Iapetus

BASIC 10LINER CONTEST 2026

=============

TITLE    : Zezito Back to Basics

AUTHOR   : Sandro "Iapetus" Mestre

PLATFORM : Commodore 64

LANGUAGE : COMMODORE 64 BASIC V2

CATEGORY : PUR-80 

CODE(C64Studio):

0W=56320:E=1024:X=7:Y=X:I=X:K=Y:SP=3:T=251:O=32:Z1=128:S$="################"
1R=40:DEFFNG(M)=(M>.)-(H>.):DEFFNQ(P)=INT(RND(1)*14)+P:PRINT"{WHITE}{HOME}{CLR}{2DOWN}";S$:R$="JOY #2"
2FORN=.TO13:PRINT"#";SPC(14);"#":NEXT:PRINTS$::PRINTR$:PRINT"NO WAY OUT? PRESS Q"
3RN=RND(-(TI+VAL(TI$))):F=255-PEEK(W):A=FAND4:B=FAND8:C=FAND1:D=FAND2:H=B:L=FNG(A)
4P=(F=144)AND(SP>.):NX=FNQ(1):NY=FNQ(3):X=X+L+(L*(PEEK(E+Y*R+X+L)<>O)):H=D
5L=FNG(C):Y=Y+L+(L*(PEEK(E+(Y+L)*R+X)<>O)):POKE-(F<>Z1)*(E+NY*R+NX)-(F=Z1)*T,35
6U=E+Y*R:S=S-((X<>I)OR(Y<>K)):POKEE+K*R+I,46:POKEU+X,.:I=X:K=Y:PRINT"{HOME}SCORE";S
7SP=SP+P:PRINT"SPADES";SP:M=(P)AND(X<14):POKE-M*(U+X+1)-(M=.)*T,O
8M=(P)AND(Y>3):POKE-M*(E+((Y-1)*R)+X)-(M=.)*T,O:GETA$:IFA$<>"Q"THENGOTO3
9PRINT"{HOME}{CLR}GAME OVER! SCORE:";S:PRINT"PRESS FIRE TO PLAY AGAIN!":WAITW,16,16:S=.:GOTO0
RUN

STORY

Zezito finds himself again inside Zulmira’s castle, where he must paint the floor of a certain room with a special paint that keeps those nasty snails from sliding around and leaving their revolting slime everywhere. That way, the next time he pops in to foil one of Zulmira’s new schemes, he won’t have to tiptoe around like a frightened cat. His mission is to paint as many floor tiles as he can—but the task is far from simple. The witch Zulmira is determined to meddle and will gleefully conjure wall blocks to cut off his path. To make matters worse, Zezito can’t step on any tile he has already painted, or the magic paint will vanish in a puff of sparkles.

Luckily, Zezito isn’t completely outmatched. He carries three trusty spades! One spade clears one tile above him and another to his right whenever things get too cramped. And best of all, he has a special teleportation potion for the moment he becomes totally boxed in, letting him zip safely back home before Zulmira can cackle in triumph.

PLAYING THE GAME

Use joystick in port 2, press fire to use a spade.

Key "Q" ends the game.

@ = Zezito

# = Wall

. = Painted floor

CODE EXPLANATION

Line 0: W=joy2 port;E=screen address; X,Y,I,K Zezito coordinates; spades= 3; T=ZP address to poke when not poking to the screen; O= space character code; Z1= mask to check joystick idle or not; S$= string to plot the top and bottom of the border around the play area.

Line 1:  R=number of screen columns; Function FNG to calculate how much to add to the coordinate variables when moving, -1,0,1; Function FNQ to return a random number to define the coordinates to plot walls at random places; Set color to white, home, clear Screen, move cursor down twice; print top of the playing area border; R$=string info about which joystick to use.

Line 2: Plot vertical and bottom walls of the border around the play area. Print info string R$. Print information on screen that the player needs to press Q to terminate game.

Line 3: Perform RND. Read joy 2 port, check the possible positions; L=movement step in X.

Line4: P=check if fire was pressed and if there is a spade to use, define variables NX,NY = where to plot a new wall; Check the tile Zezito is going to move into, if it is different than the space character then update X coordinate accordingly.

Line5: L=movement step in Y. Check the tile Zezito is going to move into, if it is different than the space character then update Y coordinate accordingly; plot wall(#).

Line6: U=screen base plus Y times the screen width in chars.If Zezito moved to a new position, increments score, plot a dot(.) where Zezito was previously; Plot Zezito(@); Update Zezito secondary coordinates; print the score.

Line7: Decrement number of spades if one was used; Print the text 'SPADES' and number of spades available to the player; M+Poke=If fire was pressed, delete char to the right of Zezito if not part the border.

Line8: M+Poke=If fire was pressed, delete char above Zezito if not part the border; check for the 'Q' key to end the game. If 'Q' was not pressed go back to line 3 and continue game.

Line9: Key "Q" was pressed, print game over and the score, and instructs the player to press fire if s/he wants to play again; Wait for fire and when it is pressed jump to line 0 for a new game.