Magic Carpet Ride (Atari 8 Bit) by Eric Carr

Magic Carpet Ride - BASIC 10Liner Contest 2024

==============================================

Author:   Eric Carr

Language: Atari BASIC Rev B/C

Platform: Atari 8-bit

Category: PUR-80

Video:

Requirements:

System: Atari 8-bit w/ 48KB+ memory (XL/XE) w/ Joystick

Emulator: Atari800MacX (on Mac) or Altirra (Windows)

BASIC ROM Cartridge if on emulator - REV B attached with submission

Background

==========

Inspired by Disney's Aladdin movie, I came up with the idea of a Aladdin riding a carpet, dodging arrows and collecting hearts. I ran out of space for hearts, but still arrived at a fun little endless dodging game that starts slow and quickly gets difficult.

Gameplay

========

The game starts immediately. Use your joystick to dodge up/down, and press joystick button on game end to start again.

Code Overview

=============

I brainstormed a method to quickly move a large character (24x18 pixels in this case) in built-in Atari BASIC:

1. Shift entire screen up/down by a single POKE to the display list screen memory pointer.

2. Since this makes the entire main screen move, I use the text window mode to show the score on the bottom. 

3. Use player/missile graphics to shoot arrows to player

4. Animate the carpet to make it look like it is flying (flapping in the wind). I use a custom charset for the player

5. To accomplish this, I use a custom location for the charset and screen locations, using Atari Strings to control the game graphics

Line by Line explanation

========================

Lines 0-5: Initialize the game

Lines 6-9: Game loop

0 GR.13:SE.0,2,4:POKE40311,71:POKE40314,75::DI.Z$(128),Y$(17032-ADR(Z$)),B$(4000)

  1. Set graphics mode 13

  2. Set color register 0

  3. Update Display List to convert bottom text window to different font size and hide rest of window

  4. Dimension Z$ (empty array buffer, used to clear Player/Missile memory for arrows)

  5. Dimension a dummy Y$ string array to position our $B buffer where I need it in memory.

     The custom charset starts at 16384, and the custom screen memory follows afterward.

     The B$ buffer (the part we overwrite with the custom characters starts at 17032)

1 B$=".":B$(4000)=B$:B$(2)=B$:Z$=B$:F.I=16513TO16591:POKEI,PEEK(40960+I):N.I:X=99

  1. Clear the B$ buffer 

  2. Set Z$ to the clear B$ buffer as well

  3. Copy the 0-9 numbers from character ROM to our custom charset location

  4. Set initial arrow X position. The arrow is not drawn yet, so this serves as a little delay before the first arrow comes.

2 B$(8)="..."

  1. Set custom charset (Our character riding on the magic carpet)

3 POKE88,231:POKE89,68:SE.1,0,0:B$(86)="..."

  1. Update our custom screen location to memory 88,89, so PRINT #6 statements work

  2. Set color register 1

  3. Set rest of custom charset (Our character riding on the magic carpet)

4 POKE54279,72:POKE559,46:POKE756,64:P=53252:POKEP+25,2:POKEP+26,0:D=9:M=1:C=238

 1. Set Player Missile Base to 72

 2. Set SDMCTL to 46: Standard playfield width, enable Player/Missiles

 3. Set custom character base to 64 (256*64=16384)

 4. Store memory location to check for collisions (53252)

 6. Set GRACTL(53277)to 2 (Turn on Players)

 7. Clear the collision register (POKE 53278 or P+26,0)

 8. Initialize arrow speeD var (D), Carpet Animation flap vars C and M

5 SE.2,0,14:SE.3,1,12:SE.4,7,8:POKE40301,68:?#6,"   abc":?#6,"akefgh":?#6,"ijdlmn"

 1. Set color registers 2,3, and 4

 2. Set the display list significant byte (40301) to point to our custom screen location (68*256)

 3. Print our hero on the screen using the custom character set

== Start of game loop ==

6 POKE40300,Y*40:L=STICK(0)/2:T=L/2+.25:POKE17733+G,M+C-G*127:G=NOTG:IFG THENM=-M

 1. Set character Y position by updating where the Display List Points to as the start of screen memory

 2. Read the joystick into L. L will be even for upleft/up/upright stick positions.

 3. Compute T - it will be even if it is left/right/middle (DOWN not pressed)

 4. Poke the appropriate screen location to animate the carpet. I alternate between two characters,

    in two screen locations: 11 12 22 21, repeat

 5. Toggle G which helps in animating the carpet characters

7 Y=Y+SGN((L=INT(L))*6+(T=INT(T))*3-Y):IFPEEK(P)THENSE.4,0,0:ONSTRIG(0)GOTO7:RUN

 1. Move the player Y (vertical position) toward its target value:

    Joystick UP: 6 (L is even)

    Joystick left/right/center: 3 (T is even)

    Joystick DOWN: 0 (Neither L or T are even)

 2. Check for collision with arrow (P). If so, darken screen and wait for button press to restart. 

8 X=X-D:POKE53248,X:ONX>30GOTO6:SO.0,150-D,10,8:D=D+.5*(D<18):IFF THENB$(1809)=Z$

 1. Move the arrow toward the player.

 2. If the arrow is still onscreen, GOTO 6 (continue game loop)

 3. Otherwise:

  1. Play a sound, increase arrow speed for the next arrow (D) up to a max of 18

  2. Every alternate round, if flag F is set, clear the player/missile area (set to Z$). 

     Instead of clearing every round, I do this every other round to allow for the possibility 

     of two arrows being shot to add to the challenge.

9 X=220:F=NOTF:?"[esc][delete]";S;:S=S+10:B$(1809+INT(RND(0)*3)*24)="ARROW SPRITE":SO.0,0,0,0:GOTO6

 This continues the code from line 8 which runs after an arrow goes offscreen

 1. Reset the arrow position to the right of the screen

 2. Toggle if we should clear arrow player/missile next round (flag F)

 3. Print the score. I use [esc][delete] char to clear the current text line when updating the score

 4. Increment the score. I increment it after printing, so the first print will display "0".

 5. Copy the arrow sprite at one of three locations (randomly) in player/missile memory.

 5. Finally, clear sound, then GOTO 6 to resume normal game loop

TOOLS / SOURCES

===============

- Atari FontMaker - Defining chars as block sprites (Game character)

  https://github.com/matosimi/atari-fontmaker

- SprEd - Player Missile Graphics Sprite editor (Arrows)

  https://bocianu.gitlab.io/spred

- Atari800MacX and Altirra - Emulators

- Aladdin sprite sheet (I modified/added the carpet)

  https://www.spriters-resource.com/game_boy_gbc/aladdingameboycolor/sheet/45559/

- Aladdin image for game manual sourced from:

  https://www.pinterest.com/pin/553450241704560250/