Globber Plus (Commodore 64) by Metzelwurst

GLOBBER PLUS (10 LINER CONTEST 2026) by Sönke Schultz

Author: Sönke Schultz (Metzelwurst)

Platform: C64

Language: Commodore BASIC V2

Category: PLUS

(goto https://schultz-fl.de/globber/plus/ for more Information)

**** GAME DESCRIPTION ****

You are GLOBBER, a brave creature with googly eyes! Race through the highway full of dangerous stones! Collect hearts for bonus points and reach the finish line to reach the next level.

Watch out: Stones change direction at the halfway point! Sound on! The game has cool sound effects - turn up the volume!

**** PLUS CATEGORY ****

This version uses the PLUS category: Background graphics, title images and background music may be loaded from external storage.

A small demo is shown before the game, and the background (race track) is created by character manipulation.

The gameplay remains identical to the GLOBBER-EXTREM-256 version.

**** CONTROLS ****

Joystick 1 (Up/Down) or Keys Q=Up / A=Down

Hearts: Light red brings more points than the dark red

**** LINES OVERVIEW ****

01 Initialize game: Setup variables, sound & sprites

02 Load sprite data, setup arrays & race track

03 Initialize player & stones, set start positions

04 Main game loop: Read joystick/keyboard input, sprite data (player)

05 Update player position, move stones

06 Set stone positions, check collision & animate

07 Check heart collision, update score & sound

08 Loop back to main game, sprite data (player, stones and hearts)

09 Level complete! Increase difficulty & continue

10 Game over, play sad sound & restart

**** BASIC code (developed in C64Studio) ****

01 RESTORE:L=1:C=5:R=3:Z=5:U=54272:V=53268:T=13:FORI=UTOU+24:POKEI,0:NEXT:POKEU+24,15:D=832:FORI=0TO188:POKED+I,0:NEXT:FORI=0TO32:READA:POKED+(0*64)+I,A:NEXT:FORI=0TO32:READA:POKED+(1*64)+I,A:NEXT:FORI=0TO23:READA:POKED+(2*64)+I,A:NEXT:S=0:B=0:F=56320
02 D=16320:FORI=0TO63:POKED+I,0:NEXT:FORI=0TO23:READA:POKED+I,A:NEXT:DIMX(5),Y(5):DIMD(5):DIMHX(2),HY(2):POKEV+1,255:POKEV+3,255:POKEV+8,255:POKEV+17,12:POKEV+18,11:FORI=1TOC:FORJ=1TO30:G=1023+J+I*160:POKEG,44:POKEG+40,45:POKEG+80,46:NEXTJ,I:W=2039:Y=3
03 ?"{HOME}{DOWN}{GREY 1}UP/DOWN WITH JOY1 OR KEY Q/A":?"{GREEN}GLOBBER":POKEV+19,5:Y=Y+(C<Y):X=20:POKEW+1,T:FORN=1TO5:X(N)=265-(N*30):Y(N)=INT(RND(1)*C)+1:POKEW+N+1,15:POKEV+N+19,15:NEXTN:HX(1)=255:HY(1)=INT(RND(1)*C)+1:POKEW+7,255:HX(2)=255:HY(2)=INT(RND(1)*C)+1
04 POKEV+12,0:POKEV+25,2:POKEV+26,10:POKEW+8,255:H=PEEK(F):GETA$:K=(A$="Q"OR(HAND1)=0)-(A$="A"OR(HAND2)=0):IFK<>0ANDY+K>=1ANDY+K<=CTHENY=Y+K:DATA10,2,128,35,136,96,35,136,96,47,130,128,10,0,128,2,128,160,0,170,168,12,157,208,4,157,208,10,170,168,9,36,0
05 POKEV-19,52+Y*32:POKEU+6,40:POKEU+4,17:POKEU+1,INT(RND(1)*3)+5+9*ABS(K):FORI=1TO70:NEXT:POKEU+4,0:FORN=1TOR:D(N)=B:M=9+INT(RND(1)*8):X(N)=X(N)-M+(B*2*M):B=INT(X/150):POKEW+1,T:T=13+(XAND1):IF(X(N)<20)OR(X(N)>255)THENX(N)=255-(B*235):Y(N)=INT(RND(1)*C)+1
06 POKEV-20+(2*N),X(N):POKEV-19+(2*N),58+32*Y(N):ON-(Y(N)=Y)AND(ABS(X(N)-2-X)<19)GOTO10:NEXTN:X=X+Z:POKEV-20,X:HX(1)=HX(1)-17:POKEV-8,HX(1):POKEV-7,54+32*HY(1):HX(2)=HX(2)-13:IFB=1THEN?"{HOME}{DOWN}{GREY 2}{2SPACE}STONES CHANGE DIRECTION!{2SPACE}":IF(X>240)THENL=L+1:POKEV+12,13:GOTO09
07 POKEV-6,HX(2):POKEV-5,54+32*HY(2):FORQ=1TO2:E=HX(Q):IF(E<20)OR((HY(Q)=Y)AND(ABS(HX(Q)-X+2)<22))THENHX(Q)=255:HY(Q)=INT(RND(1)*C)+1:IF(E>20)THENS=S+Q+L:?"{HOME}{YELLOW}LEVEL:";L;"{LEFT} {LIGHT RED}SCORE: {LEFT}";S:POKEV+12,10:FORI=1TO5:POKEU+1,I*40:POKEU+4,33:FORJ=1TO20:NEXTJ,I
08 POKEU+4,0:NEXTQ:GOTO04:DATA0,160,40,2,248,190,2,200,178,0,160,40,0,128,224,0,191,170,0,170,156,4,157,0,12,188,0,10,170,168,0,96,144,2,170,0,10,89,192,41,101,112,38,149,112,37,85,240,37,151,240,7,95,192,3,255,0,5,0,80,26,129,172,25,166,172,26,170,172
09 R=R+(R<6)*(L=2ORL=7):C=C-(C>3)*(L=3ORL=9):?"{HOME}{DOWN}{GREEN}WON!":POKEU+6,40:POKEU+4,17:FORI=0TO9:POKEU+1,INT(RND(1)*9)+4:FORJ=1TO140:NEXTJ,I:POKEU+4,16:?"{HOME}{DOWN}PRESS KEY{HOME}LEVEL:";L:POKE198,0:WAIT198,1:FORI=1TO-3*(C<5):FORJ=1TO30:POKE1143+J+I*40+C*160,96:NEXTJ,I:GOTO03
10 ?"{HOME}{DOWN}{RED}GAME OVER! STONE HIT YOU!{LIGHT BLUE}":POKEU+6,40:POKEU+4,17:FORI=0TO7:POKEU+1,160-20*I:FORJ=1TO29:NEXTJ,I:POKEU+4,0:FORI=1TO50:NEXT:POKEU+6,190:POKEU+4,128:POKEV+12,2:POKE198,0:WAIT198,1:POKEV-12,0:POKEV-10,0:RUN:DATA6,170,176,1,170,192,0,171,0,0,44,0

#RetroDevStudio.MetaData.BASIC:2049,BASIC V2,uppercase,10,10
0001 REM #------------------------------#
0002 REM # RETRO-GAME FOR THE BASIC     #
0003 REM # 10 LINER CONTEST 2026        #
0004 REM # AUTHOR: SOENKE SCHULTZ       #
0005 REM #        (METZELWURST)         #
0006 REM # PLATFORM: C64                #
0007 REM # LANGUAGE: COMMODORE BASIC V2 #
0008 REM # CATEGORY: PLUS               #
0009 REM # (LOAD GLOBBER-DEMO FIRST!)   #
0010 REM #------------------------------#
0011 REM                             
0012 REM  ### #    ##  ###  ###  ### ### 
0013 REM #    #   #  # #  # #  # #   #  #
0014 REM # ## #   #  # ###  ###  ##  ### 
0015 REM #  # #   #  # #  # #  # #   # # 
0016 REM  ### ###  ##  ###  ###  ### #  #
0017 REM                             
0018 REM #------------------------------#
0020 REM # GLOBBER RUN - THE RACE!      #
0021 REM # YOU ARE GLOBBER, A BRAVE     #
0022 REM # CREATURE WITH GOOGLY EYES!   #
0023 REM # RACE THROUGH THE HIGHWAY.    #
0024 REM # FULL OF DANGEROUS STONES!    #
0025 REM # COLLECT HEARTS FOR BONUS     #
0026 REM # POINTS AND REACH THE FINISH. #
0027 REM # WATCH OUT! STONES CHANGE     #
0028 REM # DIRECTION AT HALFWAY POINT.  #
0029 REM # GET READY TO GLOB & WIN!     #
0031 REM #                              #
0037 REM #------------------------------#
0038 REM           
0039 REM #------------------------------#
0040 REM # CONTROLS:                    #
0041 REM # JOYSTICK 1: UP/DOWN          #
0042 REM # OR KEYBOARD: Q=UP / A=DOWN   #
0043 REM # MOVE BETWEEN LANES           #
0044 REM # AVOID STONES, GRAB HEARTS!   #
0045 REM # REACH FINISH LINE FOR NEXT   #
0046 REM # LEVEL!                       #
0048 REM #------------------------------#
0049 REM ################################
0059 REM #-- VARIABLES -----------------#
0060 REM A READ SPRITES DATA
0061 REM B STONE DIRECTION (0=RIGHT TO LEFT, 1=LEFT TO RIGHT)
0062 REM C NUMBER OF LINES, MAX 5, MIN 3
0063 REM D SAVE BIG NUMBERS
0064 REM E CHECK POSITION OF HEART
0065 REM F JOYSTICK INPUT
0066 REM G 
0067 REM H CHECK JOYSTIC INPUT
0068 REM I FOR SCHLEIFE
0069 REM J FOR INNER SCHLEIFE
0070 REM K MOVE STONE RIGHT OR LEFT
0071 REM L LEVEL
0072 REM M MOVE STONES BASED ON DIRECTION
0073 REM N FOR CHECKING STONES
0074 REM O 
0075 REM P 
0076 REM Q CHECK HEART COLLISION
0077 REM R NUMBER OF STONES (3-5)
0078 REM S SCORE
0079 REM T SPRITE POINTERS
0080 REM U START OF SID CHIP MEMORY
0081 REM V VIC-II SPRITE REGISTERS
0082 REM W SPRITE POINTER MEMORY LOCATION
0083 REM X PLAYER X POSITION
0084 REM Y PLAYER Y POSITION / LINE NR
0085 REM Z MOVING PLAYER SPEED
0086 REM #-- ARRAYS -------------------#
0087 REM X(5), Y(5) STONE COORDINATES
0088 REM D(5) STONE MOVE 0=LEFT 1=RIGHT
0089 REM HX(2), HY(2) HEART COORDINATES
0100 REM ###############################
0101 REM ### LINE (1) ##################
0102 REM # INITIALIZE GAME             #
0103 REM # SETUP VARS, SOUND, SPRITES  #
0104 REM ###############################
0106 REM RESTORE
0107 RESTORE
0108 REM LEVEL NR
0109 L = 1:
0110 REM NUMBER OF LINES, MAX 5, MIN 3
0111 C = 5:
0112 REM NUMBER OF STONES, MAX 5
0113 R = 3:
0114 REM MOVING PLAYER SPEED
0115 Z = 5: 
0117 REM START OF SID CHIP MEMORY
0118 U = 54272:
0119 REM VIC-II SPRITE REGISTERS
0120 V = 53268:
0122 REM SPRITE LOCATIONS
0124 REM SPRITE POINTERS PLAYER (FRAME 1 = 13, FRAME 2 = 14)
0125 T = 13:
0134 REM INITIALIZE SOUND REGISTERS
0136 FOR I = U TO U+24:
0138 POKE I, 0:
0140 NEXT:
0142 REM SET VOLUME TO MAXIMUM
0144 POKE U+24, 15:
0146 REM
0147 D = 832:
0148 REM CLEAR SPRITE MEMORY AREA
0149 FOR I = 0 TO 188:
0150 POKE D+I, 0:
0152 NEXT:
0154 REM LOAD FIRST SPRITE PATTERN (FRAME 1)
0156 FOR I = 0 TO 32:
0158 READ A:
0160 POKE D+(0*64)+I, A:
0162 NEXT:
0164 REM LOAD SECOND SPRITE PATTERN (FRAME 2)
0166 FOR I = 0 TO 32:
0168 READ A:
0170 POKE D+(1*64)+I, A:
0172 NEXT:
0174 REM LOAD STONE SPRITE PATTERN
0176 FOR I = 0 TO 23:
0178 READ A:
0180 POKE D+(2*64)+I, A:
0182 NEXT:
0184 REM INITIALIZE SCORE
0186 S = 0:
0188 REM INITIALIZE DIRECTION CHANGE FLAG
0190 B = 0:
0192 REM JOYSTICK INPUT
0194 F = 56320
0200 REM ###############################
0201 REM ### LINE (2) ##################
0202 REM # LOAD SPRITE DATA            #
0203 REM # SETUP ARRAYS & RACE TRACK   #
0204 REM ###############################
0210 D = 16320:
0212 REM LOAD HEART SPRITE PATTERN
0214 FOR I = 0 TO 63: POKE D+I, 0: NEXT:
0218 FOR I = 0 TO 23:
0220 READ A:
0222 POKE D+I, A:
0224 NEXT:
0230 REM STONE COORDINATES 
0231 DIM X(5), Y(5)
0232 REM STONE MOVE 0=LEFT 1=RIGHT
0233 DIM D(5)
0234 REM HEART COORDINATES
0236 DIM HX(2), HY(2):
0244 REM ENABLE SPRITES
0246 POKE V+1, 255:
0248 REM SET SPRITE ENABLE REGISTER
0250 POKE V+3, 255:
0251 REM ENABLE MULTICOLOR MODE FOR SPRITES
0252 POKE V+8, 255:
0264 REM SET MULTICOLOR 1 LIGHT GRAY 
0266 POKE V+17, 12:
0268 REM SET MULTICOLOR 2 GRAY 
0269 POKE V+18, 11:
0276 REM CLEAR INNER RACE TRACK
0278 FOR I = 1 TO C:
0279 FOR J = 1 TO 30:
0280 G = 1023+J+I*160: POKE G, 44:POKE G+40, 45:POKE G+80, 46:
0281 NEXT J,I:
0284 REM SPRITE POINTER MEMORY LOCATION
0285 W = 2039:
0286 REM PLAYER Y START LINE POSITION
0288 Y = 3:
0300 REM ###############################
0301 REM ### LINE (3) ##################
0302 REM # INIT PLAYER & STONES        #
0303 REM # SET START POSITIONS         #
0304 REM ###############################
0305 REM WRITE INFO
0306 ? "UP/DOWN WITH JOY1 OR KEY Q/A":
0308 ? "GLOBBER":
0309 REM SET PLAYER COLOR TO GREEN
0310 POKE V+19, 5:
0312 REM CORRECT PLAYER POSITION IF LANE IS INVALID
0313 Y = Y + (C < Y):
0320 REM INITIALIZE PLAYER
0324 REM PLAYER X POSITION
0326 X = 20:
0336 REM SET PLAYER SPRITE POINTER
0340 POKE W+1, T:
0342 REM INITIALIZE STONES
0344 FOR N = 1 TO 5:
0346 REM START OFF SCREEN WITH DIFFERENT POSITIONS
0348 X(N) = 265-(N*30): 
0350 REM RANDOM LANE
0352 Y(N) = INT(RND(1)*C)+1:
0354 REM STONE SPRITE
0360 POKE W+N+1, 15:
0362 REM STONE COLOR - DARK GRAY
0364 POKE V+N+19,15:
0370 NEXT N:
0372 REM INITIALIZE HEART (ALWAYS RIGHT TO LEFT)
0374 HX(1) = 255:
0376 REM RANDOM LINE
0378 HY(1) = INT(RND(1)*C)+1:
0386 REM HEART SPRITE
0388 POKE W+7, 255:
0390 REM INITIALIZE SECOND HEART
0391 HX(2) = 255:
0392 HY(2) = INT(RND(1)*C)+1:
0400 REM ###############################
0401 REM ### LINE (4) ##################
0402 REM # MAIN GAME LOOP              #
0403 REM # READ JOYSTIC/KEY INPUT      #
0404 REM ###############################
0407 REM BLACK BORDER
0408 POKE V+12,0:
0413 REM FIRST HEART COLOR (RED)
0414 POKE V+25, 2:
0416 REM SECOND HEART COLOR (LIGHT RED)
0417 POKE V+26, 10: 
0418 REM SECOND HEART SPRITE
0419 POKE W+8, 255:
0420 REM CHECK JOYSTIC INPUT
0422 H = PEEK(F)
0423 REM CHECK KEYBOARD INPUT
0424 GET A$:
0426 REM CHECK FOR LANE CHANGE
0429 K = (A$="Q"OR(H AND1)=0)-(A$="A"OR(H AND2)=0):IF K<>0 AND Y+K>=1 AND Y+K<=C THEN Y=Y+K:
0450 REM PLAYER SPRITE DATA (FRAME 1)
0454 DATA 10,2,128, 35,136,96, 35,136,96, 47,130,128, 10,0,128, 2,128,160
0455 DATA 0,170,168, 12,157,208, 4,157,208, 10,170,168, 9,36,0
0500 REM ###############################
0501 REM ### LINE (5) ##################
0502 REM # UPDATE PLAYER POSITION      #
0503 REM # MOVE STONES                 #
0504 REM ###############################
0510 REM UPDATE PLAYER LANE POSITION
0512 POKE V-19, 52+Y*32:
0530 REM MOVING SOUND
0533 POKE U+6,40:
0534 POKE U+4,17:
0537 POKE U+1,INT(RND(1)*3)+5+9*ABS(K):
0538 FOR I=1 TO 70:NEXT:
0544 REM STOP SOUND
0546 POKE U+4, 0:
0554 REM MOVE STONES
0556 FOR N = 1 TO R:
0560 REM STONE DIRECTION (0=RIGHT TO LEFT, 1=LEFT TO RIGHT)
0562 D(N) = B:
0563 REM MOVE STONES BASED ON DIRECTION
0564 M = 9 + INT(RND(1)*8):
0566 X(N) = X(N) - M + (B*2*M):
0584 REM CHECK IF WE'VE REACHED HALFWAY POINT, CHANGE DIRECTION OF STONES
0585 B = INT(X/150):
0586 REM HANDLE PLAYER ANIMATION
0587 POKE W+1, T:
0588 REM CHANGE PLAYER MOVING FRAME
0589 T = 13+(X AND 1):
0590 REM STONE OUTSIDE THE AREA, NEW STONE COMING
0592 IF (X(N) < 20)OR(X(N) > 255)THEN X(N) = 255 - (B*235): Y(N) = INT(RND(1)*C)+1:
0600 REM ###############################
0601 REM ### LINE (6) ##################
0602 REM # SET STONE POSITIONS         #
0603 REM # CHECK COLLISION & ANIMATE   #
0604 REM ###############################
0614 REM STONE X POSITION
0616 POKE V-20+(2*N), X(N):
0618 REM STONE Y POSITION
0620 POKE V-19+(2*N), 58+32*Y(N):
0622 REM COLLISION DETECTION
0624 REM CHECK IF STONE IS IN SAME LANE AND CLOSE ENOUGH
0626 ON -(Y(N) = Y) AND (ABS(X(N)-2 - X) < 19) GOTO 1000:
0628 NEXT N:
0640 REM UPDATE X POSITION
0642 X = X+Z:
0646 REM MOVE SPRITE
0648 POKE V-20, X:
0650 REM MOVE FIRST HEART
0654 HX(1) = HX(1) - 17:
0662 REM HEART X POSITION
0664 POKE V-8, HX(1): 
0666 REM HEART Y POSITION
0668 POKE V-7, 54+32*HY(1):
0670 REM MOVE SECOND HEART
0672 HX(2) = HX(2) - 13:
0690 REM CHECK THE DIRECTION OF THE STONES AND GLOBBER CROSSES THE FINISH LINE
0692 IF B=1 THEN ?"  STONES CHANGE DIRECTION!  ":IF (X>240) THEN L = L + 1:POKEV+12,13:GOTO 0900:
0700 REM ###############################
0701 REM ### LINE (7) ##################
0702 REM # CHECK HEART COLLISION       #
0703 REM # UPDATE SCORE & SOUND        #
0704 REM ###############################
0716 REM SECOND HEART X POSITION
0718 POKE V-6, HX(2):
0720 REM SECOND HEART Y POSITION
0722 POKE V-5, 54+32*HY(2):
0724 REM CHECK HEART COLLISION
0730 FOR Q=1 TO 2:
0732 REM POSITION OF HEART
0734 E = HX(Q):
0742 REM CHECK POSITION OF HEART, INCREASE SCORE, PLAY SOUND
0744 IF(E<20)OR((HY(Q)=Y)AND(ABS(HX(Q)-X+2) < 22)) THEN HX(Q)=255: HY(Q)=INT(RND(1)*C)+1: IF (E>20) THEN S=S+Q+L:?"LEVEL:";L;" SCORE: ";S:POKEV+12,10:FORI=1TO5:POKEU+1,I*40:POKEU+4,33:FORJ=1TO20:NEXTJ,I:
0800 REM ###############################
0801 REM ### LINE (8) ##################
0802 REM # LOOP BACK TO MAIN GAME      #
0803 REM # SPRITE DATA                 #
0804 REM ###############################
0805 REM STOP SOUND
0806 POKE U+4,0:
0810 NEXT Q:
0822 REM CONTINUE GAME LOOP
0824 GOTO 0400:
0880 REM PLAYER SPRITE DATA (FRAME 2)
0882 DATA 0,160,40, 2,248,190 ,2,200,178, 0,160,40, 0,128,224, 0,191,170
0884 DATA 0,170,156, 4,157,0, 12,188,0, 10,170,168, 0,96,144
0890 REM STONE SPRITE DATA 
0892 DATA 2,170,0, 10,89,192, 41,101,112, 38,149,112, 37,85,240, 37,151,240, 7,95,192, 3,255,0
0894 REM HEART SPRITE DATA (FIRST PART)
0896 DATA 5,0,80, 26,129,172, 25,166,172, 26,170,172
0900 REM ###############################
0901 REM ### LINE (9) ##################
0902 REM # LEVEL COMPLETE! WIN SCREEN  #
0903 REM # INCREASE DIFFICULTY & LOOP  #
0904 REM ###############################
0905 REM PLAYER WINS
0906 REM INCREASE STONES (MAX 5) TO MAKE IT EVEN MORE DIFFICULT
0907 R = R + (R<6)*(L=2ORL=7):
0908 REM REDUCE LINES ON LVL 3 AND 9 (MIN 3)
0909 C = C - (C>3)*(L=3ORL=9):
0910 REM WRITE TEXT
0911 ? "WON!"
0912 REM PLAY WINNING SOUND
0914 POKE U+6,40:
0916 POKE U+4,17:
0918 FOR I=0 TO 9:
0920 POKE U+1,INT(RND(1)*9)+4:
0922 FOR J=1 TO 140:
0924 NEXT J, I:
0926 POKE U+4,16
0928 REM WRITE TEXT AND NEXT LEVEL
0930 ? "PRESS KEYLEVEL:";L:
0932 REM CLEAR KEYBOARD
0934 POKE 198, 0:
0936 REM WAIT FOR KEYPRESS
0938 WAIT 198, 1:
0940 REM REMOVE LAST LINE
0942 FOR I = 1 TO -3*(C<5):
0944 FOR J = 1 TO 30:
0946 POKE 1143+J+I*40+C*160, 96:
0948 NEXT J,I:
0950 REM GOTO NEXT LEVEL
0952 GOTO 0300:
1000 REM ###############################
1001 REM ### LINE (10) #################
1002 REM # GAME OVER SCREEN            #
1003 REM # PLAY SAD SOUND & RESTART    #
1004 REM ###############################
1005 REM GAME OVER
1006 ? "GAME OVER! STONE HIT YOU!":
1008 REM SAD MELODIE
1010 POKE U+6,40:
1012 POKE U+4,17:
1014 FOR I=0 TO 7:
1016 POKE U+1,160-20*I:
1018 FOR J=1 TO 29:NEXT J, I:
1020 POKE U+4,0:FOR I=1 TO 50:NEXT:
1022 REM CRASH SOUND
1024 POKE U+6,190:POKE U+4,128:
1026 REM RED BORDER
1028 POKE V+12,2:
1030 REM CLEAR KEYBOARD
1032 POKE 198, 0:
1034 REM WAIT FOR KEYPRESS
1036 WAIT 198, 1:
1038 REM RESET STONE 4
1040 POKE V-12, 0: 
1042 REM RESET STONE 5
1044 POKE V-10, 0:
1050 REM RESTART GAME 
1052 RUN:
1060 REM HEART SPRITE DATA (SECOND PART)
1062 DATA 6,170,176, 1,170,192, 0,171,0, 0,44,0

**** about the developer ****

Hello, I am Sönke from Flensburg (Germany), born near Hamburg (1978). My mother bought a Comodore64 at the end of the 80s. I made my first code experiences when I was 10 years old.

And sometimes, if time (and kids) permit, i connect the c64 on TV :-)

More about me: https://schultz-fl.de/